modela	"Cone for VRML-MODELA bridge"
{
	smooth	vrml.cone.smooth : model
	{
		// parts
		var		BOTTOM=true;
		var		SIDES=true;
		if	(vrml.cone.parts%2=0)
		{
			BOTTOM=false;
		}
		if	(int (vrml.cone.parts/2)%2=0)
		{
			SIDES=false;
		}

		// MaterialBinding
		var		nmater=vrml.mater.num;
		if (!(vrml.matebnd.value=vrml.enum.PER_PART
			| vrml.matebnd.value=vrml.enum.PER_PART_INDEXED))
		{
			nmater=1;
		}

		var		t1, x1,z1;
		var		t2, x2,z2;

		sim		vrml.cone.bottomRadius,vrml.cone.height/2,vrml.cone.bottomRadius;
		boundary	sphere	0,0,0, sqrt (3)
		{
			// poly-cone
			var		i=0;
			while	(i<vrml.cone.pn)
			{
				t1=2*PI*i/vrml.cone.pn;
				t2=2*PI*(i + 1)/vrml.cone.pn;
				x1=cos (t1);
				z1=sin (t1);
				x2=cos (t2);
				z2=sin (t2);
				if	(SIDES)
				{
					attr	vrml_attr_#(0%nmater);
					poly	"SIDES"
					{
						pt	0,1,0;
						pt	x1,-1,z1;
						pt	x2,-1,z2;
					}
				}
				if	(BOTTOM)
				{
					attr	vrml_attr_#(1%nmater);
					poly	"BOTTOM"
					{
						pt	0,-1,0;
						pt	x1,-1,z1;
						pt	x2,-1,z2;
					}
				}
				i=i + 1;
			}
		}
	}
}